Simple I2C protocol for advanced communication between Arduinos

Strong communication skills are always a key to success:

Say we have one Arduino(Slave) dedicated for position sensors and motor drives. Other slave for handling user interface tasks (displays, input controls, wifi communication). And a Master Arduino for controlling them all together. Master can ask to do any number of tasks(not just one from one Arduino).

Official Wire (I2C library for Arduino ) reference doesn’t add a lot of clarity for novices.
Good starting point is this tutorial: http://arduino.cc/en/Tutorial/MasterWriter. It just lacks of two pull-up resistors on SDA and SCL lines. Do not forget them. * Also some people report problems when multiple Arduinos are connected to one computer at the same time.

As you can see from above tutorial, communication is performed by transferring chars or bytes (max value 255). Thats not much use if you want to transfer real-life values like integers from analogRead(); or control some Digital PMW Pin.

So, second highly recommended tutorial can be found here: http://jamesreubenknowles.com/arduino-i2c-1680. It shows how to easily transfer and receive integer values by splitting them into two bytes (warning: some bitshifting involved).

Main problem for me was that I had multiple sensors on one sensor-dedicated slave. And on master’s request Wire.onRequest(); Slave could only return one value. So I made simple protocol for choosing desired sensor. The same method can be used for performing different tasks on slave, not just returning different values. You can make slave perform any function from its arsenal.

First, lets look at slave code. There are two functions for reading one or other sensor:

#define XSensorPin A1
#define YSensorPin A2

...

int GetXSensorValue(){
  int val = analogRead(XSensorPin);
  return val;
}

int GetYSensorValue(){
  int val = analogRead(YSensorPin);
  return val;
}

When slave receives command number, it executes receiveCommand(); function:

byte LastMasterCommand = 0;

void setup(){
  Wire.onReceive(receiveCommand); // register talk to slave event
}
  
...

void receiveCommand(int howMany){
  LastMasterCommand = Wire.read(); // 1 byte (maximum 256 commands), it can be easily changed to integer
}

Now when we have command (LastMasterCommand), we will wait for execution request from Master:

void setup(){
  Wire.onRequest(slavesRespond);  // Perform on master's request
}
  
...

void slavesRespond(){

  int returnValue = 0;

  switch(LastMasterCommand){
    case 0:   // No new command was received
      Wire.write("NA");
    break;
    
    case 1:   // Return X sensor value
      returnValue = GetXSensorValue();
    break;

    case 2:   // Return Y sensor value
      returnValue = GetYSensorValue();
    break;

    case 3:
       // Another useful function if received command = 3, and so on...
    break; 
    
  }

  uint8_t buffer[2];              // split integer return value into two bytes buffer
  buffer[0] = returnValue >> 8;
  buffer[1] = returnValue & 0xff;
  Wire.write(buffer, 2);          // return slave's response to last command
  LastMasterCommand = 0;          // null last Master's command and wait for next

}

Function on Master’s side for getting X Sensor value from Slave Arduino:

int GetXSensorValue(byte SlaveDeviceId){

  // SEND COMMAND 
  Wire.beginTransmission(SlaveDeviceId);
  Wire.write(1); // Transfer command ("1") to get X sensor value;
  delay(10);

  // GET RESPONSE
  int receivedValue;
  int available = Wire.requestFrom(SlaveDeviceId, (byte)2);
  if(available == 2)
  {
    receivedValue = Wire.read() << 8 | Wire.read(); // combine two bytes into integer
  }
  else
  {
    Serial.print("ERROR: Unexpected number of bytes received (XSensorValue): ");
    Serial.println(available);
  }
  Wire.endTransmission();
  
  return receivedValue;
} 

Thats all, functions can do any tasks, not only read sensors. For example they can control a motor or LED’s and return no useful data (just report successful execution).
Using same technique You can expand this simple protocol, i.e. pass a command number AND then some parameters to Slave, and then execute it. I showed basic principle.

// Simple I2C protocol for Arduino
// Master side program
// (c) 2014 Ignas Gramba
//

#include 
void setup()
{
  Wire.begin();        // join i2c bus (address optional for master)
  Serial.begin(9600);  // start serial for output
}

void loop()
{
  int x = GetXSensorValue(1); // 1 - slave's address
  Serial.print("X Sensor value: ");
  Serial.println(x);
  
  delay (100);
}

int GetXSensorValue(byte SlaveDeviceId){

  // SEND COMMAND 
  Wire.beginTransmission(SlaveDeviceId);
  Wire.write(1); // Transfer command ("1") to get X sensor value;
  delay(10);

  // GET RESPONSE
  int receivedValue;
  int available = Wire.requestFrom(SlaveDeviceId, (byte)2);
  if(available == 2)
  {
    receivedValue = Wire.read() << 8 | Wire.read(); // combine two bytes into integer
  }
  else
  {
    Serial.print("ERROR: Unexpected number of bytes received (XSensorValue): ");
    Serial.println(available);
  }
  Wire.endTransmission();
  
  return receivedValue;
} 

// Simple I2C protocol for Arduino
// Slave side program
// (c) 2014 Ignas Gramba
//
#include 

#define XSensorPin A1
#define YSensorPin A2

const byte SlaveDeviceId = 1;
byte LastMasterCommand = 0;

void setup(){
  Wire.begin(SlaveDeviceId);      // join i2c bus with Slave ID
  Wire.onReceive(receiveCommand); // register talk event
  Wire.onRequest(slavesRespond);  // register callback event

  pinMode(XSensorPin, INPUT);
  pinMode(YSensorPin, INPUT);
}

void loop(){
  delay(100);
}

void receiveCommand(int howMany){
  LastMasterCommand = Wire.read(); // 1 byte (maximum 256 commands)
}

void slavesRespond(){

  int returnValue = 0;

  switch(LastMasterCommand){
    case 0:   // No new command was received
      Wire.write("NA");
    break;
    
    case 1:   // Return X sensor value
      returnValue = GetXSensorValue();
    break;

    case 2:   // Return Y sensor value
      returnValue = GetYSensorValue();
    break;
    
  }

  byte buffer[2];                 // split int value into two bytes buffer
  buffer[0] = returnValue >> 8;
  buffer[1] = returnValue & 255;
  Wire.write(buffer, 2);          // return response to last command
  LastMasterCommand = 0;          // null last Master's command
}

int GetXSensorValue(){
  int val = analogRead(XSensorPin);
  return val;
}

int GetYSensorValue(){
  int val = analogRead(YSensorPin);
  return val;
}

Now Master sends not only command number (one byte), but 11 bytes data packet consisting of:

I plan to use functions with maximum 5 integer arguments. If You need more/less or wish to change input/output variables type it can be easily done, by examining these examples. They are completely based on previous ones. Maximum size of standard buffer in Wire library is 32 bytes.

In order to work correctly, data packet has always be the same size (even if Your function doesn’t need any arguments You have to pass zeroes or any values). Also if You are not interested in return value of any Slave’s function, than You can execute commands in Wire.onReceive(); function. There is no need to ask for return Wire.onRequest(); if You are interested in just sending data from Master to Slave. But if You have just one function that returns something, use Wire.onRequest(); everywhere. Wire likes consistency. A lot.

In this example Master creates a data packet (command number, and five integer variables), sends it to Slave, Slave performs sum of all 5 variables and returns result to Master. Master prints result in serial window. Slave acts as a math-coprocessor for the Master 🙂

Tip – if You don’t see correct answer in serial window – press “reset” button on Master, while serial window is open. This will solve early power-on miscommunication issues. Later both sides will work correctly.

// Simple I2C protocol v0.2 for Arduino
// Master side program 
// (c) 2014 Ignas Gramba
//
#include 

byte DataPacket[11];
byte command_nr;
int a, b, c, d, e; // arguments
byte SlaveDeviceId = 1;

void setup()
{
  Wire.begin();        // join i2c bus (address optional for master)
  Serial.begin(9600);  // start serial for output
  
  command_nr = 2;      // initialise test values
  a = 105;
  b = 2350;
  c = 4587;
  d = 12587;
  e = 12;  
}

void loop()
{
  makeDataPacket(command_nr, a, b, c, d, e);

  sendDataPacket();

  int response = receiveResponse();
  Serial.print("Slave response: ");
  Serial.println(response);

  while(1); // Stop
}

void makeDataPacket(byte command, int aa, int bb, int cc, int dd, int ee){
  DataPacket[0] = command;
  DataPacket[1] = aa >>  8;
  DataPacket[2] = aa & 255;
  DataPacket[3] = bb >>  8;
  DataPacket[4] = bb & 255;
  DataPacket[5] = cc >>  8;
  DataPacket[6] = cc & 255;
  DataPacket[7] = dd >>  8;
  DataPacket[8] = dd & 255;
  DataPacket[9] = ee >>  8;
  DataPacket[10]= ee & 255;
}

void sendDataPacket(){
  Wire.beginTransmission(SlaveDeviceId);
  Wire.write(DataPacket, 11);
  delay(10);
}

int receiveResponse(){
 int receivedValue;
  int available = Wire.requestFrom(SlaveDeviceId, (byte)2);
  if(available == 2)
  {
    receivedValue = Wire.read() << 8 | Wire.read(); // combine two bytes into integer
  }
  else
  {
    Serial.print("ERROR: Unexpected number of bytes received - ");
    Serial.println(available);
  }
  Wire.endTransmission(true);
  return receivedValue;  
}

// Simple I2C protocol v0.2 for Arduino
// Slave side program 
// (c) 2014 Ignas Gramba
//
#include 

const byte SlaveDeviceId = 1;
byte LastMasterCommand = 0;
int a, b, c, d, e;

void setup(){
  Wire.begin(SlaveDeviceId);      // join i2c bus with Slave ID
  Wire.onReceive(receiveDataPacket); // register talk event
  Wire.onRequest(slavesRespond);  // register callback event
}
  
void loop(){}

void receiveDataPacket(int howMany){
  //  if (howMany != 11) return; // Error
  LastMasterCommand = Wire.read();          
  a = Wire.read() << 8 | Wire.read();
  b = Wire.read() << 8 | Wire.read();
  c = Wire.read() << 8 | Wire.read();
  d = Wire.read() << 8 | Wire.read();
  e = Wire.read() << 8 | Wire.read();
}

void slavesRespond(){

  int returnValue = 0;

  switch(LastMasterCommand){
    case 0:   // No new command was received
       returnValue = 1; // i.e. error code #1
    break;
    
    case 1:   // Some function
      
    break;

    case 2:   // Our test function
      returnValue = sumFunction(a,b,c,d,e);  
    break;

  }

  byte buffer[2];              // split int value into two bytes buffer
  buffer[0] = returnValue >> 8;
  buffer[1] = returnValue & 255;
  Wire.write(buffer, 2);       // return response to last command
  LastMasterCommand = 0;       // null last Master's command
}

int sumFunction(int aa, int bb, int cc, int dd, int ee){  
  // of course for summing 5 integers You need long type of return,
  // but this is only illustration. Test values doesn't overflow

  int result = aa + bb + cc + dd + ee;
  return result;
}